HSP教室 入門編

その7 スクリーンセーバーの作り方(1)

	;	Sample 006
	;	HSP3によるスクリーンセーバーサンプル
	;	

#packopt type 2
#packopt name "sc"
	s=dir_cmdline:a=strmid(s,1,1)
	if (a="P") or (a="p") : goto *sspre		; プレビュー
	if (a="S") or (a="s") : goto *ssproc		; フルスクリーン
	if (a="C") or (a="c") : goto *sscfg		; コンフィグ
	;
	mes "Unknown switch ["+dir_cmdline+"]"
	stop

;コマンドライン解析の解説
*sscfg
	;  コンフィグ(設定画面)
	;
	tt="スクリーンセーバー"
	title tt:width 320,200:pos 8,100
	mes tt
	mes "うすあじソフト"
	pos 230,140:button "OK",*ssend
	stop
*ssend
	end
;コンフィグ画面の解説
*sspre
	;  プレビュー画面
	cls:mes "プレビュー画面":stop
;プレビュー画面の解説
	;スクリーンセーバー本体
*ssproc
	ax=ginfo_dispx:ay=ginfo_dispy	; ax,ayに画面サイズ
	bgscr 2,ax,ay,1,0,0,ax,ay	; ID2にフルスクリーン画面を作成
*textput
	font "MS ゴシック",100
	rr=rnd(255)
	xx=rnd(ginfo_winx)
	yy=rnd(ginfo_winy)
	pos xx,yy
	color rr,10,10
	mes "screen saver"
	wait 20
	goto *textput
;スクリーンセーバー本体の解説


サンプルスクリプトの各部に解説ページへのリンクがあります。
基本的な構造はこのようになっています。

(1)コマンドライン解析
(2)コンフィグ画面
(3)プレビュー画面
(4)スクリーンセーバー本体

これだけのスクリプトでスクリーンセーバーが出来てしまいます。
このサンプルはHSPのアーカイブに含まれているサンプルプログラムを参考に作ったものです。
サンプルも参考にしてみてください。

■コマンドラインってなんだ?

スクリーンセーバーが動き出すときに、Windowsからスクリーンセーバーに渡される情報があります。
これを使って動作モードを切り替えます。
これは(1)コマンドライン解析で解説してしていますが、開発中には自分の好きな値に設定したいものです。
その方法ですが、メニューの「HSP」の「起動オプション」で設定できます。
/s を指定すると、スクリーンセーバーがフルスクリーンとして起動します。





その8に行く

目次に戻る